Maven Central에 Android Library 배포하기

signing.keyId=[KEY_ID] // GPG Signing을 한후 나온 마지막 8자리 입력 ex) 45678900
signing.password=[KEY_PASSPHRASE] // GPG Signing을 할때 사용한 암호 입력
signing.secretKeyRingFile=[ABSOLUTE_PATH] // secring.gpg 파일 경로 입력 ex) /Users/user/keys/secring.gpg
ossrhUsername=[SONATYPE_USERNAME] // SonarType 아이디
ossrhPassword=[SONATYPE_PASSWORD] // SonarType 비밀번호
sonatypeStagingProfileId=[SONATYPE_STAGING_PROFILE_ID] // SonarType Profile Id ex) 11111ec1cc1b1

signing.keyId=45678900
signing.password=asdfg1234
signing.secretKeyRingFile=/Users/nayunjae/project/SlackWebhookAndroid/SecretRingKey.gpg
ossrhUsername=yunjaena
ossrhPassword=1q2w3e4r!
sonatypeStagingProfileId=11111ec1cc1b1

ext {
    PUBLISH_GROUP_ID = 'io.github.yunjaena'
    PUBLISH_VERSION = '0.0.3'
    PUBLISH_ARTIFACT_ID = 'slackwebhookandroid'
    PUBLISH_DESCRIPTION = 'SlackWebHook Android Library'
    PUBLISH_URL = 'https://github.com/yunjaena/SlackWebhookAndroid'
    PUBLISH_LICENSE_NAME = 'Apache License'
    PUBLISH_LICENSE_URL =
            'https://github.com/yunjaena/SlackWebhookAndroid/blob/main/LICENSE'
    PUBLISH_DEVELOPER_ID = 'yunjaena'
    PUBLISH_DEVELOPER_NAME = 'Yun-Jae Na'
    PUBLISH_DEVELOPER_EMAIL = 'yunjaena@gmail.com'
    PUBLISH_SCM_CONNECTION =
            'scm:git:github.com/yunjaena/SlackWebhookAndroid.git'
    PUBLISH_SCM_DEVELOPER_CONNECTION =
            'scm:git:ssh://github.com:yunjaena/SlackWebhookAndroid.git'
    PUBLISH_SCM_URL =
            'https://github.com/yunjaena/SlackWebhookAndroid/tree/main'
}

apply plugin: 'maven-publish'
apply plugin: 'signing'

task androidSourcesJar(type: Jar) {
    archiveClassifier.set('sources')
    if (project.plugins.findPlugin("com.android.library")) {
        // For Android libraries
        from android.sourceSets.main.java.srcDirs
        from android.sourceSets.main.kotlin.srcDirs
    } else {
        // For pure Kotlin libraries, in case you have them
        from sourceSets.main.java.srcDirs
        from sourceSets.main.kotlin.srcDirs
    }
}


artifacts {
    archives androidSourcesJar
}

group = PUBLISH_GROUP_ID
version = PUBLISH_VERSION

afterEvaluate {
    publishing {
        publications {
            release(MavenPublication) {
                // The coordinates of the library, being set from variables that
                // we'll set up later
                groupId PUBLISH_GROUP_ID
                artifactId PUBLISH_ARTIFACT_ID
                version PUBLISH_VERSION

                // Two artifacts, the `aar` (or `jar`) and the sources
                if (project.plugins.findPlugin("com.android.library")) {
                    from components.release
                } else {
                    artifact("$buildDir/libs/${project.getName()}-${version}.jar")
                }

                artifact androidSourcesJar

                // Mostly self-explanatory metadata
                pom {
                    name = PUBLISH_ARTIFACT_ID
                    description = PUBLISH_DESCRIPTION
                    url = PUBLISH_URL
                    licenses {
                        license {
                            name = PUBLISH_LICENSE_NAME
                            url = PUBLISH_LICENSE_URL
                        }
                    }
                    developers {
                        developer {
                            id = PUBLISH_DEVELOPER_ID
                            name = PUBLISH_DEVELOPER_NAME
                            email = PUBLISH_DEVELOPER_EMAIL
                        }
                    }

                    // Version control info - if you're using GitHub, follow the
                    // format as seen here
                    scm {
                        connection = PUBLISH_SCM_CONNECTION
                        developerConnection = PUBLISH_SCM_DEVELOPER_CONNECTION
                        url = PUBLISH_SCM_URL
                    }
                }
            }
        }
    }
}

signing {
    sign publishing.publications
}

// Create variables with empty default values
ext["signing.keyId"] = ''
ext["signing.password"] = ''
ext["signing.secretKeyRingFile"] = ''
ext["ossrhUsername"] = ''
ext["ossrhPassword"] = ''
ext["sonatypeStagingProfileId"] = ''

File secretPropsFile = project.rootProject.file('local.properties')
if (secretPropsFile.exists()) {
    // Read local.properties file first if it exists
    Properties p = new Properties()
    new FileInputStream(secretPropsFile).withCloseable { is -> p.load(is) }
    p.each { name, value -> ext[name] = value }
} else {
    // Use system environment variables
    ext["ossrhUsername"] = System.getenv('OSSRH_USERNAME')
    ext["ossrhPassword"] = System.getenv('OSSRH_PASSWORD')
    ext["sonatypeStagingProfileId"] = System.getenv('SONATYPE_STAGING_PROFILE_ID')
    ext["signing.keyId"] = System.getenv('SIGNING_KEY_ID')
    ext["signing.password"] = System.getenv('SIGNING_PASSWORD')
    ext["signing.secretKeyRingFile"] = System.getenv('SIGNING_SECRET_KEY_RING_FILE')
}

// Set up Sonatype repository
nexusPublishing {
    repositories {
        sonatype {
            stagingProfileId = sonatypeStagingProfileId
            username = ossrhUsername
            password = ossrhPassword
            nexusUrl.set(uri("https://s01.oss.sonatype.org/service/local/"))
            snapshotRepositoryUrl.set(uri("https://s01.oss.sonatype.org/content/repositories/snapshots/"))
        }
    }
}

// project build.gradle 에 추가

buildscript {
    dependencies {
        classpath 'io.github.gradle-nexus:publish-plugin:1.1.0'
    }
}

apply plugin: 'io.github.gradle-nexus.publish-plugin'
apply from: "${rootDir}/scripts/publish-root.gradle"
apply from: 'publish.gradle'